Another application I’d like to share: Media Player Classic Homecinema.

Our environment never standardized on a media player previously. I chose MPC-HC for the following reasons:

• Large number of filters and codecs come bundled
• Uses Directshow for system wide formats
• Good performance: Low memory footprint and supports hardware accelerated decoding
• Polished, mature, and feels more Windows-native than other players (VLC, PotPlayer)

As of right now, the latest version is 1.7.10. The installer is easy enough to deal with alone, but I’ve put together a batch script to deal with setting it as the default player for popular formats and disabling the auto-updater. This is particularly useful for including it in your operating system deployments.

Install script

@echo off
REM Installer
start /wait MPC-HC.1.7.10.x64 /VERYSILENT

REM HKR extension handling
"%PROGRAMFILES%\MPC-HC\mpc-hc64.exe" /regall

REM Windows Explorer extension handling
FOR %%A IN (3g2,3ga,3gp,3gp2,3gpp,aac,ac3,aif,aifc,aiff,alac,amr,amv,aob,ape,apl,asf,asx,au,avi,bdmv,bik,cda,divx,dsa,dsm,dss,dsv,dts,dtshd,dtsma,evo,f4v,flac,flc,fli,flic,flv,hdmov,ifo,ivf,m1a,m1v,m2a,m2p,m2t,m2ts,m2v,m3u,m3u8,m4a,m4b,m4r,m4v,mid,midi,mka,mkv,mlp,mov,mp2,mp2v,mp3,mp4,mp4v,mpa,mpc,mpcpl,mpe,mpeg,mpg,mpls,mpv2,mpv4,mts,ofr,ofs,oga,ogg,ogm,ogv,opus,pls,pva,ra,ram,rec,rm,rmi,rmm,rmvb,rp,rpm,rt,smi,smil,smk,snd,swf,tak,tp,trp,ts,tta,vob,wav,wax,webm,wm,wma,wmp,wmv,wmx,wv,wvx) DO FOR /F %%G IN ('reg query HKU') DO reg add %%G\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%A\UserChoice /v ProgID /t REG_SZ /d mplayerc64.%%A /f

REM Disable auto-updater
FOR /F %%G IN ('reg query HKU') DO reg add %%G\SOFTWARE\MPC-HC\MPC-HC\Settings /t REG_DWORD /v UpdaterAutoCheck /d 0 /f

Uninstall script

@echo off
"%PROGRAMFILES%\MPC-HC\mpc-hc64.exe" /unregall
"%PROGRAMFILES%\MPC-HC\unins000.exe" /verysilent /SUPPRESSMSGBOXES

REM Remove Explorer extension handlings
FOR %%A IN (3g2,3ga,3gp,3gp2,3gpp,aac,ac3,aif,aifc,aiff,alac,amr,amv,aob,ape,apl,asf,asx,au,avi,bdmv,bik,cda,divx,dsa,dsm,dss,dsv,dts,dtshd,dtsma,evo,f4v,flac,flc,fli,flic,flv,hdmov,ifo,ivf,m1a,m1v,m2a,m2p,m2t,m2ts,m2v,m3u,m3u8,m4a,m4b,m4r,m4v,mid,midi,mka,mkv,mlp,mov,mp2,mp2v,mp3,mp4,mp4v,mpa,mpc,mpcpl,mpe,mpeg,mpg,mpls,mpv2,mpv4,mts,ofr,ofs,oga,ogg,ogm,ogv,opus,pls,pva,ra,ram,rec,rm,rmi,rmm,rmvb,rp,rpm,rt,smi,smil,smk,snd,swf,tak,tp,trp,ts,tta,vob,wav,wax,webm,wm,wma,wmp,wmv,wmx,wv,wvx) DO FOR /F %%G IN ('reg query HKU') DO reg delete %%G\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%A\UserChoice /f

Make sure your application deployment runs as System. Detection of mpc-hc64.exe can be done by simple existence, but the file version is accurate.

Cheers!

Read MoreComments